Delphi 的內存操作函數(6): 跨進程的內存分配

Delphi 為我們提供了三個方便的函數:

GlobalAllocPtr {簡化自 API 的 GlobalAlloc}
GlobalReAllocPtr {簡化自 API 的 GlobalReAlloc}
GlobalFreePtr {簡化自 API 的 GlobalFree}

讀寫本程序以外的數據時可以使用它們, 很方便, 譬如:

p := GlobalAllocPtr(0, Len); {分配}
p := GlobalReAllocPtr(p, Len, 0); {重分配}
GlobalFreePtr(p); {釋放}

注意 GlobalAllocPtr 的第一個參數和 GlobalReAllocPtr 的最后一個參數, 上面給的都是 0;

這兩個參數的意義是一樣的, 規范一點應該寫成 GMEM_FIXED (表示分配固定內存), 常用的參數還有:

GMEM_MOVEABLE {分配可移動內存}
GMEM_ZEROINIT {同時清空內存}
GHND {分配可移動內存同時清空}
GPTR {分配固定內存同時清空}

參數還有很多, 和相應的 API 函數的參數是一致的.

下面的例子并沒有使用進程以外的對象, 可以把 Memo1.Handle 換做外部的其他文本容器(譬如記事本)試一試:

代碼文件:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  p: Pointer;
  Len: Integer;
begin
  Len := 6+1;                    {假如想要讀出 6 個字符, 要留出結束的空字符}
  p := GlobalAllocPtr(0, Len*2); {分配內存 Len*2 是針對雙字節字符}
  SendMessage(Memo1.Handle, WM_GETTEXT, Len, Cardinal(p));
  ShowMessage(PChar(p)); {CodeGe}
  GlobalFreePtr(p);
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  p: Pointer;
  Len: Integer;
begin
  Len := 6+1;                    {假如想要讀出 6 個字符, 要流出結束的空字符}
  p := GlobalAllocPtr(0, Len*2); {分配內存 Len*2 是針對雙字節字符}
  SendMessage(Memo1.Handle, WM_GETTEXT, Len, Cardinal(p));
  ShowMessage(PChar(p)); {CodeGe}

  {在上一例的基礎上繼續, 先獲取實際長度}
  Len := SendMessage(Memo1.Handle, WM_GETTEXTLENGTH, 0, 0);
  Len := (Len + 1) * 2;
  p := GlobalReAllocPtr(p, Len, GHND); {重新分配內存}
  SendMessage(Memo1.Handle, WM_GETTEXT, Len, Cardinal(p));
  ShowMessage(PChar(p)); {CodeGear Delphi 2009}

  GlobalFreePtr(p);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Align := alLeft;
  Memo1.ScrollBars := ssVertical;
  Memo1.Text := 'CodeGear Delphi 2009';
end;

end.

窗體文件:

object Form1: TForm1
  Left = 0
  Top = 0
  Caption = 'Form1'
  ClientHeight = 151
  ClientWidth = 295
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  OnCreate = FormCreate
  PixelsPerInch = 96
  TextHeight = 13
  object Memo1: TMemo
    Left = 8
    Top = 8
    Width = 169
    Height = 89
    Lines.Strings = (
      'Memo1')
    TabOrder = 0
  end
  object Button1: TButton
    Left = 192
    Top = 32
    Width = 75
    Height = 25
    Caption = 'Button1'
    TabOrder = 1
    OnClick = Button1Click
  end
  object Button2: TButton
    Left = 192
    Top = 72
    Width = 75
    Height = 25
    Caption = 'Button2'
    TabOrder = 2
    OnClick = Button2Click
  end
end

例：獲取打開的記事本中的內容

procedure TForm1.Button1Click(Sender: TObject);
var
  h: HWND;
  p: Pointer;
  Len: Integer;
begin
  h := FindWindow('Notepad', nil);
  if h = 0 then Exit;
  h := GetWindow(h, GW_CHILD);
  if h = 0 then Exit;
  Len := SendMessage(h, WM_GETTEXTLENGTH, 0, 0) + 1;
  p := GlobalAllocPtr(0, Len * SizeOf(Char));
  SendMessage(h, WM_GETTEXT, Len, Cardinal(p));
  ShowMessage(PChar(p));
  GlobalFreePtr(p);
end;